@echo off

cls
echo ==========================================
echo = Easy Wii ISO .gct Cheat Embedder v1.00 =
echo =                                        =
echo =           Pack + Script by:            =
echo =         damysteryman/Team DARK         =
echo =        Updates by ppPooPoo69420        =
echo =                                        =
echo =              Powered by:               =
echo =      Wiimms ISO Tool v3.00a r7387      =
echo =      Wiimms SZS Tool v1.54a r7393      =
echo =                by Wiimm                =
echo =                                        =
echo =        More info in README.txt         =
echo ==========================================
pause

SET WITPATH=%cd%\Easy_Wii_ISO_gct_Cheat_Embedder_v1.00_dmm\wit-v3.00a-r7387-cygwin\bin\wit
SET SZSPATH=%cd%\Easy_Wii_ISO_gct_Cheat_Embedder_v1.00_dmm\szs-v1.54a-r7393-cygwin\bin\wstrt

IF "%~1"=="" GOTO ISOFAIL
for /f %%i in ('%WITPATH% ID6 "%~1"') do set GAMEID=%%i
IF NOT EXIST %cd%\Easy_Wii_ISO_gct_Cheat_Embedder_v1.00_dmm\gct\%GAMEID%.gct GOTO GCTFAIL

SET FILENAME=%~n1
SET WORKDIR=%FILENAME%-UNPACK

%WITPATH% extract -1p "%~1" --DEST "%WORKDIR%" --psel data -ovv
%SZSPATH% patch "%WORKDIR%/sys/main.dol" --add-sect %cd%\Easy_Wii_ISO_gct_Cheat_Embedder_v1.00_dmm\gct\%GAMEID%.gct -ovv
%WITPATH% copy "%WORKDIR%" --DEST "%FILENAME% + GCT_EMBED.iso" -ovv

rd /S /Q "%WORKDIR%"

echo.
echo OK, should be finished now!
echo Look for the file [%FILENAME% + GCT_EMBED.iso] in the same folder as this script!
GOTO END

:ISOFAIL
echo.
echo Please Drag and drop your Wii .iso onto this .bat script file in order for it to work!
echo.
GOTO END

:GCTFAIL
echo.
echo %GAMEID%.GCT not found!
echo Please make sure your .gct file is in the 'gct' folder, and is named %GAMEID%.GCT
echo.

:END
pause